How To Enable/Disable IE Proxy By Using VBS

Today you gonna learn a easy method to enable/disable IE proxy by using a vbs script so lets get started just open notepad and paste this code

'#==============================================================================
'#==============================================================================
'#  SCRIPT.........:  Enable Disable IE Proxy.vbs
'#  AUTHOR.........:  Stuart Barrett
'#  VERSION........:  1.0
'#  CREATED........:  15/09/10
'#  COPYRIGHT......:  2010
'#  LICENSE........:  Freeware
'#  REQUIREMENTS...:  
'#  DESCRIPTION....:  Enables or disables IE proxy on the local system
'#
'#  NOTES..........:  
'# 
'#  CUSTOMIZE......:  
'#==============================================================================
'#  REVISED BY.....:  
'#  EMAIL..........:  
'#  REVISION DATE..:  
'#  REVISION NOTES.:
'#
'#==============================================================================
'#==============================================================================

Const HKEY_CURRENT_USER = &H80000001
Set objShell = CreateObject("WScript.Shell")
strPC = objShell.ExpandEnvironmentStrings("%COMPUTERNAME%")

On Error Resume Next

Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings"
strValueName = "ProxyEnable"

objReg.GetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,dwValue

'#==============================================================================
'# If IE Proxy is currently enabled display message and ask user whether it
'# should then be disabled
'#==============================================================================
If dwValue = 1 Then
 IEPrompt = MsgBox ("IE Proxy is currently ENABLED on " & strPC & _
 ".  Do you want to DISABLE it?", vbQuestion+vbYesNo, "Disable IE Proxy")
 If IEPrompt = vbYes Then
  dwValue = 0
  objReg.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,dwValue 
  MsgBox "IE Proxy is now DISABLED on " & strPC & _
  ".",vbInformation, "Disable IE Proxy"
  ElseIf IEPrompt = vbNo Then
   MsgBox "IE Proxy is still ENABLED on " & strPC & _
   ".",vbInformation, "Disable IE Proxy"
 End If
 '#==============================================================================
 '# If IE Proxy is currently disabled display message and ask user whether it
 '# should then be enabled
 '#==============================================================================
 ElseIf dwValue = 0 Then
  IEPrompt = MsgBox ("IE Proxy is currently DISABLED on " & strPC & _
  ".  Do you want to ENABLE it?", vbQuestion+vbYesNo, "Enable IE Proxy")
  If IEPrompt = vbYes Then
   dwValue = 1
   objReg.SetDWORDValue HKEY_CURRENT_USER,strKeyPath,strValueName,dwValue
   MsgBox "IE Proxy is now ENABLED on " & strPC & _
   ".",vbInformation, "Enable IE Proxy"
   ElseIf IEPrompt = vbNo Then
    MsgBox "IE Proxy is still DISABLED on " & strPC & _
    ".",vbInformation, "Enable IE Proxy"
 End If
End If

then go to file > save as and then change the filename to "Enable Disable IE Proxy.vbs" then go to the destination of the file and double click it then if proxy dis you will see a message like this

 if you want to enable proxy in IE Click yes

click ok now proxy is enabled in IE

if you want to disable proxy in IE open the file again then you will see this message

click yes

click ok now proxy is disabled in IE